剣と魔法の物語(The tale of a Sword and Sorcery)

剣と魔法の物語(The tale of a Sword and Sorcery)

Introduction

塔内を探索して三種の神器を集め、最上階にいるドラゴンを倒し、囚われの姫君を救出するゲームです。
増設RAM(OR-1/E)ありのPB-100シリーズで遊べます。

 
スクリーンショット
RUN RAD STOP
_ Ω H _ F _ H o _ : 2
<実行画面1>塔を探索! まずは鍵を探そう。
RUN RAD STOP
G e t K E Y
<実行画面2>鍵をゲット。出口はどこだ!?
RUN DEG STOP
_ Ω - o O _ _ H _ : 1
<実行画面3>発見! しかし出口前に魔物が!

 

Game Story and System

プロローグ
遥か遠い昔から語り継がれてきた数多の物語や伝承…。
その大半は、危険を押し切って、成功の覚束ないことに命を賭けた、勇敢な冒険者達のお話だ。
邪悪な大魔王から世界を救った勇者の話とか、伝説の財宝を探し当てた盗賊の話…。
この膨大な数の書物に記された英雄達の冒険物語は、いつの時代にも人々に大きな夢を与えてくれる…。
まだあどけなさが残る、この二人の少年と少女にも…。
◆ストーリー#1:へっぽこ騎士(ナイト)と囚われの姫君〜The Tower Of Babydi〜
ここは、魔王とその魔王を倒した勇者の伝説が残る、ラインハルト王国。
人々は心優しい王様と姫君に守られ、今ではすっかり平和な日々を過ごしておられます。
この物語の主人公セシルは、おっとりとした性格で、口数の少ない少年ですが、王国に仕えるナイトの一人です。
ある日の夜、悪夢で目が覚めたセシルは、不吉な予感に駆られ、姫君の城へと向かいます。
しかし、セシルが城のテラスへ辿り着いた時、突如巨大な翼を持った怪物が現れ、姫君はあっさりと、城の北にある魔王山へと連れ去られてしまいました。
どうやら姫君を連れ去ったのは、過去に倒されたはずの「魔王」のようです。
姫君を救出するため、こうしてセシルの最初の冒険が始まったのです。
◆How To Play
あなたは主人公を操作して、塔の最上階にいるドラゴンを倒し、囚われた姫君を救い出さなければいけません。
姫君が囚われている“バビデの塔”は、5つのワールド(部屋)で構成されており、脱出するには“鍵”が必要になります。
“鍵”を手に入れることが出来ると、各ワールドのとある場所に“ゲート(扉)”が出現します。
その“ゲート”に飛び込み、次のワールドに移動してください。
また、各ワールドには、ドラゴンの創り出した魔物達が数多く潜んでおり、主人公の行く手を阻みます。
しかし、恐れることはありません。装備している武器で効率良く魔物達をやっつけてください。
魔物達と戦って経験を積むと、それに応じてレベルがあがります。
レベルがあがると最大HPと攻撃力がアップします。

なお、ドラゴンのいる最上階に辿り着くには、塔内のどこかに隠されている“三種の神器”が必要です。

 

Characters

登場キャラクタ
キャラクタパターン 説明
Ω へっぽこ騎士(ナイト)
本編の主人公
姫君
o すらいむ
HP:1〜2 Exp:1〜2
m いもむし
HP:3〜4 Exp:3〜4
w かにかに
HP:5 Exp:5
<= ° E Σ @ ドラゴン(防御体勢)
° E- Σ @ ドラゴン(攻撃体勢)
 

Worldview

冒険の舞台:ワールド1紹介
各ワールドは、3フロア構成。はしごを使って各フロアを上り下りします。
RUN DEG STOP
  _ _ _ _ _ _ _   : 3
<説明画面1>ワールド1の3階
RUN GRA STOP
_ _ H _ _ _ H _ _ : 2
<説明画面2>ワールド1の2階
RUN RAD STOP
_ H _ _ H _ _ H _ : 1
<説明画面3>ワールド1の1階
◆バビデの塔(ダンジョン)構成物
キャラクタパターン 説明
_
H 階段
  落とし穴
F
O ゲート(扉)
◆アイテム:三種の神器
キャラクタパターン 説明
クリスタル
最上階の結界を破る
] ドラゴンシールド
ドラゴンの炎を防ぐ最強の盾
ドラゴンバスター
「竜殺し」という意味を持つ剣
 

Operation Guide

基本操作説明
このゲームは、“アドベンチャーモード”と“ラストバトルモード”で操作方法が異なります。
◆アドベンチャーモード
4
左へ移動します
6
右へ移動します
2
階段を降ります
8
階段を登ります
0
ステータスウインドウを開く
Z
攻撃(剣を振る)
EXE
画面送り、決定
◆ラストバトルモード
Z
攻撃(剣を振る)
X
防御(盾を構える)
EXE
画面送り、決定
 
◆攻撃可能位置 ※アドベンチャーモード時
主人公が魔物達を攻撃する場合には、攻撃可能位置が設定されています。
点滅している地点がその位置範囲です。この範囲外では、剣は振れません。
魔物達を攻撃する際は、十分に注意してください。
RUN DEG
Ω _ _ _ _ _ _ _ o : 1
<説明画面4>攻撃可能位置
◆ワープ通路 ※アドベンチャーモード時
主人公のみ、フロアの両端のワープ通路を使用することが出来ます。
点滅している地点がワープ通路の出入口です。
ただし、ワープ通路への侵入口が床の場合に限ります。
RUN DEG
_ _ : 1
<説明画面5>ワープ通路
 

Program Execution

プログラムの入力
剣と魔法の物語(The tale of a Sword and Sorcery)for PB-100+増設RAMのプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 0 EXE
メモリ(変数)を設定
プログラムの実行
剣と魔法の物語(The tale of a Sword and Sorcery)for PB-100+増設RAMのプログラムの入力後、下記の操作を実行するとゲームスタートです。
◆初めからゲームを開始する場合
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 9
指定されたプログラムエリア[P9]のプログラムを実行
◆中断したゲームを再開する場合
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行

<注意!>
ゲームの中断はいつでも可能ですが、中断後は変数の内容を誤って破壊しないように注意してください。

 

Technical Documentation

Program List for PB-100
剣と魔法の物語のプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(660×743pixel)で見ることが出来ます。
Program List for PB-SIM

[P0]
1 G=0:IF W<>6;GOSUB #1:GOTO 3
2 PRINT "¥C2<SAVE ME!":GOTO #8
3 F=1:U=1:V=1:GOSUB #2
4 IF G=1;IF MID(V+X,1)="O";PRINT :W=W+1:GOTO 1
5 IF MID(V+X,1)="F";GOSUB 14:G=1
6 IF MID(V+X,1)=" ";Y=Y-1
7 IF KEY="4";X=X-1:Z=-1:IF X<0;X=8
8 IF KEY="6";X=X+1:Z=1:IF X>8;X=0
9 IF KEY="Z";A$="-":IF X<>0;IF X<>8;PRINT CSR X+Z;A$;:GOSUB 16
10 IF KEY="2";IF Y>1;IF MID(V+X-9,1)="H";Y=Y-1
11 IF KEY="8";IF MID(V+X,1)="H";Y=Y+1
12 IF KEY="0";GOSUB #5
13 V=Y*9-8:F=Y:GOSUB #4:GOTO 4
14 PRINT :PRINT "Get KEY";:GOSUB #3
15 $=MID(1,V+X-1)+"_"+MID(V+X+1):$=MID(1,4)+"O"+MID(6):RETURN
16 IF X+Z<>INT P;RETURN
17 PRINT CSR INT P;"*";:N=N-L:IF N>1;RETURN
18 E=E+W:IF E>=2^L*4;IF L<=7;L=L+1:E=0:GOSUB 23
19 IF L>=W+1;IF W-1=H;IF RAN#<.1;GOSUB 24
20 P=INT (RAN#*9):IF P<>X;IF P<>X+1;IF P<>X-1 THEN 22
21 GOTO 20
22 N=W:Q=Y:U=1:RETURN
23 PRINT :PRINT "Lv UP!!";:GOSUB #3:M=L*10:RETURN
24 PRINT :PRINT "Get ITEM ";D$;:GOSUB #3:H=H+2:B$=B$+D$:RETURN

[P1]
1 GOSUB 3+W:PRINT "WORLD";W:M=L*10:N=W:P=8:Q=1:X=0:Y=1
2 FOR F=1 TO 3:V=F*9-8:GOSUB #2
3 STOP:NEXT F:RETURN
4 $="_H__H__H___H_F_H__ _______ ":C$="o":D$="¥DI":RETURN
5 $="__H___H__ H__H__H __ _F_ __":RETURN
6 $="__H____H_H__H F H _ ___ ___":C$="m":D$="]":RETURN
7 $="H_H___H_H_ _H H_ HF _____ _":RETURN
8 $="H_H_H___H_H_ H F H ____  __":C$="w":D$="¥RA":RETURN

[P2]
1 MODE Q+3:PRINT CSR 0;MID(V,9);CSR 9;F;CSR 9;":";
2 IF Y=F;PRINT CSR X;"¥OM";
3 IF Q=F;PRINT CSR INT P;C$;:IF X=INT P;PRINT CSR X;"*";:GOSUB #6
4 RETURN

[P3]
1 FOR I=0 TO 99:NEXT I:RETURN

[P4]
1 IF MID(U+P,1)=" ";Q=Q-1
2 IF Y<Q;IF MID(U+P-9,1)="H";Q=Q-1
3 IF Y>Q;IF MID(U+P,1)="H";Q=Q+1
4 P=P+(SGN(X-P)/10):U=Q*9-8:GOSUB #2:RETURN

[P5]
1 PRINT :PRINT L;CSR 0;"L";CSR 3;"H:";M;"/";L*10
2 IF L<>8;PRINT "E:";E;"/";2^L*4
3 PRINT "ITEM:";B$:RETURN

[P6]
1 M=M-W:IF M>1;RETURN
2 PRINT :PRINT "GAME OVER";

[P8]
1 C$="¥LE¥DG¥EX":D$=">¥DG¥EM":N=99:M=L*10
2 IF LEN(B$)<>3;PRINT "Once Again!":W=1:GOTO #0
3 Z=0:A$=" ":R=INT (RAN#*2):PRINT CSR 0;"¥OM";CSR 7;C$(R);"¥SG@";
4 FOR I=0 TO L
5 IF KEY="Z";Z=2:A$="¥RA":GOSUB 14:IF R=0 THEN 11
6 IF KEY="X";Z=1:A$="]":GOSUB 14
7 NEXT I:IF R<>1;PRINT :GOTO 3
8 FOR J=6 TO 1 STEP -1:PRINT CSR J;"w";:NEXT J
9 IF Z<>1;PRINT CSR 0;"*";:GOSUB #6
10 GOTO 13
11 FOR J=2 TO 7:PRINT CSR J;")";:NEXT J
12 IF R=0;PRINT CSR 8;"*";:N=N-L:IF N<1;PRINT "Fin";:END
13 GOSUB #3:PRINT :GOTO 3
14 PRINT CSR1;A$;:RETURN

[P9]
1 VAC :B$="":L=1:W=1:GOTO #0
2 REM "TSS_STORY#1"
3 REM "  2012/09/15"
4 REM "  AUTHOR:HIE"

 
変数表
変数 説明
マップデータ
A$ 主人公装備品
B$ 取得アイテム
C$,D$ 魔物キャラクタ、お宝、ドラゴン
経験値
フロア
鍵フラグ
アイテムフラグ
I,J ループ用(汎用)
主人公レベル
主人公HP
魔物HP
P,Q 魔物座標
ドラゴン表示用
魔物位置データ取得用
主人公位置データ取得用
ワールド
X,Y 主人公座標
主人公方向フラグ、ドラゴン戦闘用
 
プログラムマップ
[P0] メインルーチン(614step)
行番号 説明
ワールド判定
ラストバトル開始処理
初期設定
4〜6 主人公移動判定
7〜8 キー入力判定(左右移動)
キー入力判定(攻撃)
10〜11 キー入力判定(上下移動)
12 キー入力判定(ステータス表示)
13 主人公位置情報設定他
14〜15 鍵取得処理
16〜17 攻撃&ダメージ計算処理
18 経験値&レベルアップ判定処理
19 戦闘後処理
20〜22 魔物再配置処理
23 レベルアップ処理
24 アイテム取得処理
[P1] サブルーチン#1(297step)
行番号 説明
ワールド表示初期設定
2〜3 ワールド全体図表示
4〜8 ワールドデータ
[P2] サブルーチン#2(85step)
行番号 説明
メイン画面描画
主人公描画
魔物描画
メインルーチンへ
[P3] サブルーチン#3(15step)
行番号 説明
表示ウェイト短処理
[P4] サブルーチン#4(107step)
行番号 説明
1〜3 魔物移動判定(上下移動)
魔物移動判定(左右移動)
[P5] サブルーチン#5(74step)
行番号 説明
1〜3 ステータス表示
[P6] サブルーチン#6(33atep)
行番号 説明
主人公ダメージ計算処理
ゲームオーバー処理
[P8] サブルーチン#7(321step)
行番号 説明
初期設定
三種の神器判定
メイン画面描画
4〜7 キー入力判定
8〜10 ドラゴン攻撃処理
11〜13 主人公攻撃処理
14 主人公装備品描画
[P9] イニシャライズ(22step ※注釈行含めず)
行番号 説明
初期設定
2〜4 注釈行※この行以降は無視
 
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
¥C2
¥DI
¥RA
Ω ¥OM
<= ¥LE
° ¥DG
E ¥EX
E- ¥EM
¥SG

 

COMMENT

遊びましたよ〜。三種の神器の入手方法が分からず、リストを解析してしまいました。面白かったです。
  • よなぷー
  • 2015/05/05 4:16 PM






   

PAGE TOP