BOMBBOMB

BOMBBOMB(ボムボム)

Introduction

モンスターをうまく誘導して、爆弾(ボム)でこらしめるゲームです。
増設RAM(OR-1/E)ありのPB-100シリーズで遊べます。


<注意!>
プログラムの実行前に、必ず DEFM 4(要32step) してください。

 
スクリーンショット
RUN DEG
o 9 q : 3
<実行画面1>爆弾(ボム)をセットして…
RUN DEG
o 1 q : 3
<実行画面2>モンスターをおびき寄せ…
RUN DEG
o ( * ) : 3
<実行画面3>こらしめる!?

 

Game Story and System

ゲーム内容
どこまでもひたすら主人公を追いかけてくるモンスター。
このモンスターをうまく誘導して、爆弾でこらしめてください。
規定数のモンスターをこらしめるとラウンドクリアです。
モンスターにつかまったり、爆風に巻き込まれたり、ラウンド3以降に登場するお邪魔釘を踏んだりするとミスとなります。
3回ミスすると、ゲームオーバーです。

※爆弾(ボム)をセットすると、 9 1 へとカウントダウンが始まり、最後には爆発します。


<注意!>
プログラムの実行前に、必ず DEFM 4(要32step) してください。

 

Characters

登場キャラクタ
キャラクタパターン 説明
o 不思議な館に迷い込んだ男の子
本編の主人公
q
p
モンスター(左向き)
モンスター(右向き)
. お邪魔釘
9 爆弾(ボム)
 

Operation Guide

基本操作説明
4
左へ移動します
6
右へ移動します
Z
ジャンプ
X
爆弾(ボム)セット
EXE
画面送り、決定
 
◆ジャンプ開始&爆弾(ボム)セット可能位置
主人公がモンスターやお邪魔釘をジャンプでかわす場合には、ジャンプ開始可能位置が設定されています。
また、主人公が爆弾(ボム)をセットする場合にも、爆弾(ボム)セット可能位置が設定されています。
点滅している地点がその位置範囲です。
ジャンプや爆弾(ボム)を使用するときは、十分に注意してください。
RUN DEG
o _ _ _ _ _ _ _ q : 3
<説明画面1>ジャンプ&爆弾(ボム)設置可能位置
◆ワープ通路
主人公のみ、ステージの両端のワープ通路を使用することが出来ます。
点滅している地点がワープ通路の出入口です。
RUN DEG
_ _ : 3
<説明画面2>ワープ通路
 

Program Execution

プログラムの入力
BOMBBOMB for PB-100+増設RAMのプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 4 EXE
メモリ(変数)を設定

<注意!>
プログラムの実行前に、必ず DEFM 4(要32step) してください。

 
プログラムの実行
BOMBBOMB for PB-100+増設RAMのプログラムの入力後、下記の操作を実行するとゲームスタートです。
◆初回起動時(ファーストブート)
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 9
指定されたプログラムエリア[P9]のプログラムを実行
◆初回起動時以降(ホットスタート)
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行
 

Technical Documentation

Program List for PB-100
BOMBBOMBのプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(660×743pixel)で見ることが出来ます。
Program List for PB-SIM

[P0]
1 $="  BOMBBOMB  ":Z(4)=0:F$="(":G$=")"
2 FOR I=9 TO 1 STEP -1:PRINT CSR 4;I;:GOSUB #5:NEXT I
3 FOR I=4 TO 0 STEP -1:GOSUB #5:PRINT CSR I;F$;CSR 5;"*";CSR 10-I;G$;
4 NEXT I:GOSUB #3:STOP:PRINT "HI";H,"BY ";K$:GOTO #1

[P1]
1 M=3:Q=.1:R=1:S=0:Z=1:Z(2)=1
2 L=R*20:Z(1)=1:Z(3)=L:MODE 4
3 $=" READY GO!! ":Z(4)=0:F$="o":G$=A$:X=0
4 PRINT :PRINT "ROUND";R,"ENEMY";Z:IF R>=3;GOSUB 20
5 GOSUB #4:N=0:O=0:P=0:T=9:Y=8
6 $="123456789"
7 PRINT CSR X;F$;CSR Y;A$(O);CSR 9;":";M;
8 IF R>=3;PRINT CSR D;C$;CSR E;C$;:GOSUB 21
9 IF KEY="4";V=X:GOSUB 28:X=X-1:P=-1:IF X<0;X=8
10 IF KEY="6";V=X:GOSUB 28:X=X+1:P=1:IF X>8;X=0
11 IF KEY="Z";IF P<>0;IF X<>0;IF X<>8 THEN 31
12 IF KEY="X";IF N<>1;IF X<>0;IF X<>8;N=1:W=X
13 IF X<Y;O=0:V=Y:GOSUB 28:Y=Y-Q*Z(1)
14 IF X>Y;O=1:V=Y:GOSUB 28:Y=Y+Q*Z(1)
15 IF X=INT Y THEN 22
16 IF N=1;PRINT CSR W;MID(T,1);:T=T-1:IF T<1 THEN 35
17 L=L-Z(1)/2:IF INT L=Z(3)/2;GOSUB 19:Z(1)=2:MODE 6
18 GOTO 6
19 $=" HARRY UP!! ":GOSUB #3:GOSUB #6:RETURN
20 I=INT(RAN#*4):D=I+1:E=D+3:RETURN
21 IF X<>D;IF X<>E;RETURN
22 $=" GAME OVER! ":F$="+":G$="¥CR"
23 FOR I=0 TO 2:FOR J=5 TO 6:PRINT CSR X;A$(J);:GOSUB #5:NEXT J:NEXT I
24 M=M-1:IF M<>0;V=X:GOSUB 28:GOTO 3
25 GOSUB #4:PRINT "SC";S;:IF H<S;H=S:PRINT CSR 8;"[NR]":GOTO 27
26 STOP:GOTO #0
27 INPUT "Name",K$:PRINT "  Thanks!":GOTO #0
28 PRINT CSR V;" ";:RETURN
29 PRINT CSR U;"¥DG";:GOSUB 28:X=X+P:RETURN
30 PRINT CSR V;"   ";:RETURN
31 FOR U=X TO X+P*1 STEP P
32 IF U<=0;U=0:GOSUB 29:V=U:GOSUB 28:P=0:X=8:GOTO 6
33 IF U>=8;U=8:GOSUB 29:V=U:GOSUB 28:P=0:X=0:GOTO 6
34 V=U:GOSUB 29:NEXT U:GOTO 6
35 PRINT CSR W-1;"(*)";
36 IF X>=W-1;IF X<=W+1;V=W-1:GOSUB 30:GOTO 22
37 IF W-1<=INT Y;IF W+1>=INT Y THEN 39
38 V=W-1:GOSUB 30:N=0:T=9:GOTO 6
39 $="ROUND CLEAR!":F$="¥DI":G$=F$
40 S=S+R*10:Z=Z-1:V=W-1:GOSUB 46:IF Z<>0;GOSUB 30:GOTO 3
41 GOSUB #4:GOSUB 44:R=R+1:Z=R:IF Z>5;Z=5
42 IF R=2*Z(2);Q=Q+.1:Z(2)=Z(2)+1:IF Q>=.5;Q=.5
43 GOTO 2
44 IF L<=0; PRINT CSR 2;"NO BONUS";:GOSUB #6:RETURN
45 PRINT CSR 1;"BONUS";INT L*10;:S=S+INT L*10:GOSUB #6:RETURN
46 PRINT CSR V;R*10;:GOSUB #5:RETURN

[P2]
1 FOR I=0 TO 5:PRINT CSR I;F$;CSR 11-I;G$;:GOSUB #5:NEXT I:RETURN

[P3]
1 FOR I=5 TO 0 STEP -1:GOSUB #5
2 PRINT CSR I;MID(I+1,1);CSR 11-I;MID(11-I+1,1);
3 NEXT I:RETURN

[P4]
1 GOSUB #2:GOSUB #3:STOP:RETURN

[P5]
1 Z(4)=Z(4)+2^2:RETURN

[P6]
1 FOR I=0 TO 99:NEXT I:PRINT :RETURN

[P9]
1 VAC:A$="q":B$="p":C$=".":K$="HIE":H=160:GOTO #0
2 REM "BOMBBOMB"
3 REM "  2012/07/21"
4 REM "  AUTHOR:HIE"

 
変数表
変数 説明
爆弾(ボム)
A$,B$ モンスター…A$(0)〜A$(1)
C$ お邪魔釘
D,E お邪魔釘座標
F$ 主人公、エフェクト用代入キャラクタ
G$ エフェクト用代入キャラクタ
ハイスコア
I,J ループ用(汎用)
K$ ハイスコアラー
タイムボーナス初期値
主人公ストック数
爆弾(ボム)用フラグ
モンスター移動用フラグ
主人公ジャンプ用フラグ
モンスター移動量
ラウンド
スコア
爆弾(ボム)カウンタ
ループ(ジャンプ用)
座標記憶用
爆弾(ボム)座標
主人公座標
モンスター座標
モンスター数(ノルマ)
Z(1) モンスター移動倍率
Z(2) 難易度調整用
Z(3) タイムボーナス記憶用
Z(4) 表示ウェイト用
 
プログラムマップ
[P0] タイトルデモ(138step)
行番号 説明
初期設定
2〜4 デモ(タイトル、ハイスコア表示)
[P1] メインルーチン(1213step)
行番号 説明
1〜2 初期設定
3〜6 ラウンドスタート設定
7〜8 画面表示
9〜12 キー入力
13〜14 モンスター移動処理
15 主人公&モンスター衝突判定
16 爆弾処理
17〜18 タイムカウント
19 HARRY UP!!制御
20 お邪魔釘配置設定
21〜27 主人公ミス&ゲームオーバー処理
28〜30 描画&消去制御
31〜34 主人公ジャンプ処理
35〜38 爆発処理
39〜46 スコア&ラウンドクリア処理
[P2] サブルーチン#1(35step)
行番号 説明
画面エフェクト#1
[P3] サブルーチン#2(57step)
行番号 説明
1〜3 画面エフェクト#2
[P4] サブルーチン#3(14step)
行番号 説明
画面エフェクト制御
[P5] サブルーチン#4(18step)
行番号 説明
表示ウェイト短
[P6] サブルーチン#5(17step)
行番号 説明
表示ウェイト長
[P9] イニシャライズ(44step ※注釈行含まず)
行番号 説明
初期設定
2〜4 注釈行※この行以降は無視
 
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
× ¥CR
° ¥DG
¥DI

 

COMMENT







   

PAGE TOP