Wild Gunman Type C

Wild Gunman Type C(ワイルドガンマン)

Introduction

次々と現れる悪漢を相手に、ガンファイトを繰り広げるゲームです。
増設RAM(OR-1/E)なしのPB-100シリーズで遊べます。


※参考文献等
任天堂 FC「ワイルドガンマン」 GAME MODE C

 
スクリーンショット
RUN DEG
<実行画面1>ゲーム画面
RUN DEG
<実行画面2>悪漢を撃て
RUN DEG
<実行画面3>見事、命中!

 

Game Story and System

ゲーム内容
画面上の3つの窓から、次々と現れる悪漢を相手に、ガンファイト(銃の早撃ち決闘)を繰り広げます。
相手に撃たれる前に、悪漢を狙撃してください。悪漢は、同時に3人現れることがあります。
持ち弾は15発です。10人の悪漢に勝利すると1面クリアです。
また、窓から一般市民が姿を現した場合は、狙撃せずに、やり過ごしてください。
誤って狙撃すると、ゲームオーバーです。
なお、悪漢を撃ち損じると、1人につき1ミスとなり、3回ミスでゲームオーバーです。
持ち弾が無くなってもゲームオーバーです。


※参考文献等
任天堂 FC「ワイルドガンマン」 GAME MODE C

 

Characters

登場キャラクタ
キャラクタパターン 説明
悪漢
一般市民
 

Operation Guide

基本操作説明
4
左の窓に向かって射撃
5
真ん中の窓に向かって射撃
6
右の窓に向かって射撃
EXE
画面送り、決定
 

Program Execution

プログラムの入力
Wild Gunman Type C for PB-100のプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 0 EXE
メモリ(変数)を設定
 
プログラムの実行
Wild Gunman Type C for PB-100のプログラムの入力後、下記の操作を実行するとゲームスタートです。
 
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行
 

Technical Documentation

Program List for PB-100
Wild Gunman Type Cのプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(570×327pixel)で見ることが出来ます。
Program List for PB-SIM

[P0]
10 VAC:M=3:R=1:S=0:W=6
20 E=10:Z=15
30 PRINT "GAME";R:IF W<1;W=1
40 PRINT CSR0;"[+][+][+]";M;" ";:GOSUB 210
50 PRINT CSR1;MID(4,1);CSR4;MID(5,1);CSR7;MID(6,1);
60 FOR J=1 TO 3:FOR K=0 TO W
70 IF KEY="4";X=1:H=4:A$=D$:GOTO 140
80 IF KEY="5";X=4:H=5:B$=D$:GOTO 140
90 IF KEY="6";X=7:H=6:C$=D$:GOTO 140
100 NEXT K:NEXT J
110 FOR I=0 TO 2
120 IF MID(I+4,1)="¥SP";IF A$(I)<>D$;M=M-1:IF M<=0 THEN 150
130 NEXT I:GOTO 40
140 PRINT CSR X;D$;:IF Z>=1;Z=Z-1:GOTO 160
150 PRINT :PRINT "(¥CR_¥CR)/ LOST!":GOSUB 200:GOTO 10
160 IF MID(H,1)="¥SP";S=S+10:E=E-1
170 IF MID(H,1)="¥CL" THEN 150
180 IF E<=0;PRINT :PRINT "(*'-')¥MU WON!":R=R+1:W=W-.5:GOTO 20
190 GOTO 100
200 PRINT "SCORE";S:RETURN
210 FOR I=0 TO 2:A$(I)=" ":NEXT I:$="¥SP¥CL ":D$="*"
220 FOR I=1 TO 3:$=$+MID(INT(RAN#*3)+1,1):NEXT I
230 FOR I=0 TO 2:A$(I)=MID(I+4,1):NEXT I
240 RETURN
250 REM "WildGunman#C"
260 REM "  2012/05/27"
270 REM "  AUTHOR:HIE"

 
変数表
変数 説明
キャラクタ配置データ
A$,B$,C$ 命中判定用データ…A$(0)〜A$(2)
悪漢数
命中判定用フラグ
ループ用(汎用)
J,K ループ用(キー入力)
ダメージ
ラウンド
スコア
難易度調整用
弾丸座標
弾丸数
プログラムマップ
[P0] メインルーチン(538step ※注釈行含めず)
行番号 説明
10〜 初期設定
30〜 ラウンド表示
40〜 画面設定
50〜 悪漢&一般市民表示設定
60〜 キー入力
110〜 悪漢射撃判定
140〜 自分射撃判定
200 スコア表示
210〜 表示データ&命中判定用設定
250〜 注釈行※この行以降は無視
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
¥SP
× ¥CR
¥CL
μ ¥MU

 

COMMENT







   

PAGE TOP