PB-SPACE HARRIER

PB-SPACE HARRIER

Introduction

超能力戦士ハリアーとなって、ドラゴンランドに巣食う魔生物をショットガンで倒していくゲームです。
増設RAM(OR-1/E)ありのPB-100シリーズで遊べます。


※参考文献等
セガ 「スペースハリアー」

 
スクリーンショット
RUN DEG STOP
[ _ S T A G E 1 _ ] 0
<実行画面1>走れ! 撃て! スペースハリアー! ドラゴンランドに平和を取り戻すのだ!
RUN DEG STOP
[ _ - I o I I _ ] 0
<実行画面2>まずは前方から迫りくる障害物を避けながら、ステージを突き進めもう!
RUN DEG STOP
[ _ - o W ¥ W _ ] 2
<実行画面3>WARNING! 魔生物が現れた! ショットガンで粉砕せよ!

 

Game Story and System

ストーリー
遥かな宇宙の果てにある平和なドラゴンランドは、突如発生した超自然現象と正体不明の凶悪な魔生物たちの襲撃により、その様相はすっかり変わってしまっていた。
正義のドラゴン“ユーライア”の悲痛な要請を受けた若き超能力戦士ハリアーは、ドラゴンランドの危機を救うべく、愛用のショットガンを携え、単身ドラゴンランドへと飛び立ったのである。

 
◆How To Play
このゲームは、超能力戦士ハリアーを操作して、魔生物(ボスキャラクタ)を倒していく疑似3Dシューティングゲームです。
障害物は破壊できないため、うまく避けながら突き進んでください。
ステージを一定以上突き進むと魔生物が出現しますが、滞在時間を経過すると逃げ出してしまいますので、その前に愛用のショットガンで撃破してください。
障害物に衝突したり、魔生物の攻撃にやられると、ハリアーの体力が減っていきます。※各ステージの魔生物を倒すと若干回復します。
ハリアーの体力が0(ゼロ)になると、ゲームオーバーです。


 

Characters

登場キャラクタ
キャラクタパターン 説明
o 超能力戦士ハリアー
本編の主人公
障害物
柱(遠)
i 障害物
柱(中)
I 障害物
柱(近)※この状態で当たるとダメージ
W ¥ W 魔生物(ボスキャラクタ)
無防備状態(ショットガン使用可能/弱点:顔)
m ¥ m 魔生物(ボスキャラクタ)
爪攻撃状態(ショットガン使用不能/両爪に当たるとダメージ)
 

Operation Guide

基本操作説明
4
左へ移動します
6
右へ移動します
Z
ショットガン使用 ※魔生物(ボスキャラクタ)戦のみ
EXE
画面送り、決定
 

Program Execution

プログラムの入力
PB-SPACE HARRIER for PB-100+増設RAMのプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 0 EXE
メモリ(変数)を設定
プログラムの実行
PB-SPACE HARRIER for PB-100+増設RAMのプログラムの入力後、下記の操作を実行するとゲームスタートです。
◆初回起動時(ファーストブート)
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 9
指定されたプログラムエリア[P9]のプログラムを実行
◆初回起動時以降(ホットスタート)
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行
 

Technical Documentation

Program List for PB-100
PB-SPACE HARRIERのプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(660×730pixel)で見ることが出来ます。
Program List for PB-SIM

[P0]
10 A$="  - -  ":B$=" -   - ":C$="-     -":M=32:S=0:X=5:Z=1
20 $="":PRINT "HI";H,"BY ";K$
30 N$="STAGE":T=Z:Y=0:FOR I=0 TO 2:O=1:GOSUB #8:O=4:GOSUB #8:NEXT I
40 D$="¥DT":E$="i":F$="I":G=1:IF Y>9 THEN 100
50 FOR I=0 TO 2:IF I=0;GOSUB #7:GOTO 70
60 P=P+U:Q=Q+V:R=R+W
70 O=1:GOSUB #8:O=6:GOSUB #8:GOSUB #6
80 NEXT I:IF X<>P;IF X<>Q;IF X<>R;Y=Y+1:S=S+Z*10:GOTO 40
90 GOSUB 220:Y=0:GOTO 40
100 N$="WARNING":L=Z+1:T=L:Y=16
110 FOR I=0 TO 2:O=2:GOSUB #8:O=5:GOSUB #8:NEXT I
120 D$="..¥DT":E$=" .;":F$=" ;¥DT":G=1:U=0:IF Y<1 THEN 280
130 GOSUB #7:FOR I=0 TO 2:O=2:GOSUB #8:O=7:GOSUB #8:GOSUB #6:NEXT I
140 D$="":G=2:Q$="W¥¥W":U=0
150 FOR I=0 TO 2
160 O=3:GOSUB #8:GOSUB #6:IF L=0;GOSUB #8:GOTO 350
170 NEXT I:PRINT CSR P;"m¥¥m";:GOSUB 210
180 D$=";. ":E$="¥DT. ":F$=".  ":G=1:U=0
190 FOR I=0 TO 2:O=2:GOSUB #8:O=7:GOSUB #8:GOSUB #6:NEXT I
200 Y=Y-1:GOTO 120
210 IF X<>P;IF X<>P+2;RETURN
220 PRINT CSR X;"*";:GOSUB #4:M=M-T:IF M>=0;RETURN
230 PRINT CSR 1;"GAME OVER";:GOSUB #5
240 PRINT :PRINT "SC";S;
250 IF H<S;H=S:PRINT CSR 8;"[NR]":GOTO 270
260 STOP :GOTO 10
270 INPUT "Name",K$:PRINT "  Thanks!":GOTO 10
280 N$="ESCAPED":FOR I=0 TO 2:O=2:GOSUB #8:O=5:GOSUB #8:NEXT I
290 Z=Z+1:IF Z<>9 THEN 30
300 IF LEN($)<>8;GOSUB #5:GOSUB 340:$="":Z=1:GOTO 30
310 GOSUB #5:PRINT :PRINT CSR 11;"All enemy was destroyed.";
320 PRINT "The battle is over.","BONUS";M*100
330 S=S+M*100:GOTO 240
340 PRINT :PRINT CSR 11; "Sorry,To do over from scratch.":RETURN
350 D$="+":E$="¥CR":F$=" ":$=$+E$
360 FOR I=0 TO 2:FOR J=0 TO 2:PRINT CSR P+I;D$(J);:NEXT J:NEXT I
370 S=S+Z*100:M=M+Y*Z:GOTO 290

[P4]
10 FOR J=0 TO 9:NEXT J:RETURN

[P5]
10 FOR J=0 TO 99:NEXT J:RETURN

[P6]
10 IF KEY="4";IF X>2;X=X-1
20 IF KEY="6";IF X<8;X=X+1
30 IF G=2;IF KEY="Z";U=1:PRINT CSR X-1;"¥TR";CSR X+1;"¥TR";
40 PRINT CSR X;"o";
50 IF U=1;IF G=2;IF P+1<=X;IF P>=X-1 THEN 70
60 G=1:U=0:RETURN
70 PRINT CSR P;Q$;CSR P+1;"¥CR";
80 G=1:L=L-1:S=S+Z*10:U=0:RETURN

[P7]
1 GOTO G*10
10 P=INT(RAN#*3)+4:U=INT(RAN#*3)-1
11 Q=INT(RAN#*3)+4:V=INT(RAN#*3)-1
12 R=INT(RAN#*3)+4:W=INT(RAN#*3)-1:RETURN
20 P=INT(RAN#*5)+2:RETURN

[P8]
1 GOTO O*10
10 PRINT CSR 0;"[_";A$(I);CSR 10;Y;CSR 9;"_]";:RETURN
20 PRINT CSR 0;"[_";A$(I);CSR 10;L;CSR 9;"_]";:RETURN
30 PRINT CSR 0;"[_";A$(I);CSR 10;L;CSR P;Q$;CSR 9;"_]";:RETURN
40 PRINT CSR 2;N$;Z;:RETURN
50 PRINT CSR 2;N$;:RETURN
60 PRINT CSR P;D$(I);CSR Q;D$(I);CSR R;D$(I);:RETURN
70 PRINT CSR P;D$(I);:RETURN

[P9]
10 VAC:H=1600:K$="HIE":GOTO #0
20 "PB-Space Harrier"
30 " 2014/10/25"
40 " AUTHOR:HIE"
変数表
変数 説明
ボス討伐フラグ
A$〜C$ コースアニメーションデータ…A$(0)〜A$(2)
D$〜F$ 障害物(柱)/ボスアニメーションデータ…D$(0)〜D$(2)
ゲームモードフラグ(1:柱回避/2:ボス戦)
ハイスコア
I,J ループ用
K$ ハイスコアラー
魔生物(ボスキャラクタ)HP
ハリアーHP
N$ 文字制御用
画面制御用
P,Q,R 障害物(柱)/魔生物(ボスキャラクタ)表示座標
※ボス戦時:Q$=ボスモーションデータ
スコア
難易度調整用(ダメージ値)
U,V,W 障害物(柱)移動方向
※ボス戦時:U=ショットガンフラグ
ハリアー座標
コース移動距離
ステージ数
 
プログラムマップ
[P0] メインルーチン(1052step)
行番号 説明
10 初期設定(各種初期データ定義)
20 ハイスコアラー表示
30 ゲーム開始前処理(変数設定、ステージ数表示)
40〜90 障害物(柱)回避モード処理
100〜200 魔生物(ボスキャラクタ)出現&討伐モード処理
210〜270 ハリアーダメージ&ゲームオーバー処理
280 魔生物(ボスキャラクタ)退散処理
290〜340 ステージクリア&エンディング処理
350〜370 魔生物(ボスキャラクタ)撃破処理
[P4] ウェイト制御(短)(14step)
行番号 説明
10 表示ウェイト処理
[P5] ウェイト制御(中)(15step)
行番号 説明
10 表示ウェイト処理
[P6] キー入力制御(176step)
行番号 説明
10〜80 キー入力判定、ショットガン処理
[P7] 表示座標制御(97step)
行番号 説明
モード判定処理
10〜12 障害物(柱)座標設定
20 魔生物(ボスキャラクタ)座標設定
[P8] 画面表示制御(190step)
行番号 説明
画面表示判定処理
10〜30 各ゲームモードメイン画面表示
40〜50 演出用画面表示
60〜70 障害物(柱)/魔生物(ボスキャラクタ)表示
[P9] イニシャライズ(24step ※注釈行含めず)
行番号 説明
10 初期設定
20〜40 注釈行※この行は無視
 
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
¥DT
¥¥
× ¥CR

 

COMMENT







   

PAGE TOP