BRAVE SAGA

BRAVE SAGA

Introduction

謎の魔術師にさらわれた、エクレール王国のショコラ姫を助け出すゲームです。
増設RAM(OR-1/E)ありのPB-100シリーズで遊べます。


※参考文献等
任天堂 FC「スーパーマリオブラザーズ」

 
スクリーンショット
RUN DEG STOP
B R A V E S A G A
<実行画面1>RPGっぽいタイトルだけど、横スクロールのジャンプアクションゲームw
RUN DEG STOP
[ o _ _ _ _ ] : $ 0
<実行画面2>穴に落ちないように、障害物を避けながら、ゴールへたどりつこう!
RUN DEG STOP
[ _ _ $ ] : $ 0
<実行画面3>$(コイン)を発見! 確実にゲットして高得点を狙おう!

 

Game Story and System

プロローグ
世の中には、どうしても対決が避けられない者同士という関係があるようで…。
ここ“スウィーツランド”にも、

東に、ひたむきで心優しい性格のカスタード王国のタルト王子。
西に、ものぐさでいい加減な性格のホイップ王国のトルテ王子。

とまあ、なんとも対照的な二人の王子がおりまして、
今日も性懲りもなく、決着のつかないどうでもいい対決を繰り広げていました。

参考までに、みなさんにこれまでの対戦成績をお伝えしておきますと…。

なんと!?

99戦0勝0敗全引き分けと、実に超あり得ない戦績ではありますが、
二人は小さな頃から、れっきとしたライバル同士でした…。

 
◆ストーリー#1:美しき姫君と二人の王子!?の巻
ここは、カスタード王国とホイップ王国のちょうど真ん中に位置するエクレール王国。
この王国には、とても美しい姫君がいました。

慈悲と慈愛に満ちたそのお姫様は、名をショコラといい、
彼女は、タルト王子とトルテ王子がひそかに心を寄せる相手でもありました。

ショコラ姫の誕生日を明日に控え、エクレール王国はいつになく緊迫していました。

城内ではお祝いの宴の準備が慌ただしく進められ、
式典に出席する各国の代表も次々と王国入りしている最中、
そんな時に事件は起こりました。

突如、エクレール王国の上空を暗雲が覆い、
大地を揺るがすほどの凄まじい雷鳴がとどろくと、
強烈な閃光が一気にお城に襲い掛かりました。

そして、突如現れた謎の魔術師に、ショコラ姫がさらわれてしまったのです。

国中の人々が絶望と孤独に包まれ、深い悲しみに暮れました。

けれどその中でただ一人、内に秘めた情熱を燃やし、ある決意を固めた者がいました。

一足お先にエクレール王国を訪れていたカスタード王国のタルト王子が
さらわれたショコラ姫を救い出すために立ち上がったのです。

果たして、タルト王子はショコラ姫を無事助け出すことが出来るのか!?
それにしても、こんな一大事にトルテ王子は何をしているのか!?
これはそんな二人の王子が繰り広げる、愛と勇気の冒険の物語です。

 
◆How To Play
このゲームは、タルト王子(あなた)を操作してゴールを目指す、ジャンプアクションゲームです。
謎の魔術師にさらわれたショコラ姫を無事に助け出してください。
ただし、落とし穴に落ちたり、トラップ(突起物)に触れたりするとゲームオーバーです。

 

Characters

登場キャラクタ
キャラクタパターン 説明
o カスタード王国のタルト王子
本編の主人公
 

Worldview

冒険の舞台:エリア1紹介
BRAVE SAGA_AREA1_全体MAP
 
◆エリア構成物
キャラクタパターン 説明
$ コイン※着地状態でゲット出来ます
  落とし穴
. トラップ(突起物)
_ 歩道
_ i _ チェックポイント
_ P _ ゴール

Operation Guide

基本操作説明
1
小ジャンプ(1マス)
2
中ジャンプ(2マス)
3
大ジャンプ(3マス)
EXE
画面送り、決定
 

Program Execution

プログラムの入力
BRAVE SAGA for PB-100+増設RAMのプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 0 EXE
メモリ(変数)を設定
プログラムの実行
BRAVE SAGA for PB-100+増設RAMのプログラムの入力後、下記の操作を実行するとゲームスタートです。
◆初回起動時(ファーストブート)
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 9
指定されたプログラムエリア[P9]のプログラムを実行
◆初回起動時以降(ホットスタート)
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行
 

Technical Documentation

Program List for PB-100
BRAVE SAGAのプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(660×678pixel)で見ることが出来ます。
Program List for PB-SIM

[P0]
10 $="_iAi_   ":A=0:P$="o":Q$="¥CI"
20 PRINT " BRAVE SAGA ", CSR 4;T;CSR 1;N$;":"
30 W=49:X=2:Y=1:IF A<>0;$="__P__   "
40 PRINT CSR 0;$;CSR X;P$;:GOSUB #7:W=4
50 FOR I=1 TO 4:PRINT CSR 0;MID(I,5);:GOSUB #8:NEXT I
60 IF A=0;A=1:S=0:Z=1
70 B$="_":X=Z:FOR I=0 TO 6:B$(I)=B$:NEXT I
80 L=0:R=0:U=0:V=1:W=99:GOSUB #1
90 PRINT CSR 4;"AREA";A;:GOSUB #7
100 M$="":FOR I=0 TO 6:M$=M$+B$(I):NEXT I
110 PRINT CSR 0;"[";M$;"]:";L;CSR X;P$(R);CSR 10;"$";
120 IF R=0;IF B$(X-1)<>"_";IF B$(X-1)<>"$";GOSUB 230
130 IF B$(X-1)="$";IF R<>1;L=L+1:S=S+L*10:B$(X-1)="_"
140 IF B$(X-1)="i";IF R<>2;S=S+L*Z*100:GOSUB 250
150 IF B$(X-1)="P";IF R<>2;S=S+L*Z*160:A=A+1:GOTO 260
160 FOR I=0 TO ABS(5-X):K$=KEY
170 IF K$>="1";IF K$<="3";IF R=0;R=1:O=VAL(K$)+1:GOTO 190
180 NEXT I
190 O=O-1:IF O=0;R=0
200 FOR I=0 TO 6:B$(I)=B$(I+1):NEXT I
210 U=U+1:H$=MID(U,1):IF U=30;U=0:V=V+1:GOSUB #1
220 S=S+Z:GOTO 100
230 IF B$(X-1)<>"i";IF B$(X-1)<>"P" THEN 290
240 RETURN
250 K$="CHECK":W=49:Y=2:GOSUB #8:K$="POINT":GOSUB #8:RETURN
260 K$="GOAL!":W=99:GOSUB #8:Z=Z+1:IF Z>=4;Z=4
270 IF A>4;STOP :PRINT :GOSUB 350:A=1
280 PRINT :GOTO 30
290 P$="+":Q$="¥CR":W=4:Y=1:FOR I=0 TO 2:GOSUB #8:NEXT I
300 PRINT CSR 0;" GAME OVER! "
310 PRINT :PRINT "SC";S;
320 IF T<S;T=S:PRINT CSR 8;"[NR]":GOTO 340
330 STOP :GOTO 10
340 INPUT "YOUR NAME",N$:$=N$:N$=MID(1,3):GOTO 10
350 $=" THANK YOU FOR YOUR PLAYING! ":PRINT CSR 11;$;
360 $="BUT OUR PRINCESS IS IN ANOTHER":PRINT $;
370 $=" PLACE! TO BE CONTINUED.":PRINT $;:STOP:RETURN

[P1]
10 GOTO A*10+V
11 $=" _ _$  __  __$ _ __ _ $__   $ ":RETURN
12 $="___i___ $   __$ _ __ _ $__  __":RETURN
13 $="  $_ _ ___P______":RETURN
21 $="_$ __ _  _$_ ___ $  ___  _$   ":RETURN
22 $="___i___...$_..___..$.___._$_..":RETURN
23 $="_.__.$____P______":RETURN
31 $="  $ _. ._$__  _ . _$_   __$._ ":RETURN
32 $="___i___ _.$__   _$_ . _  __$_.":RETURN
33 $=" ._ $  ___P______":RETURN
41 $="_. ._ . _$_. _$_ _.$_.$.__  _.":RETURN
42 $="___i___._  __.$._$._ _$_ ._$_ ":RETURN
43 $=". _. .____P______":RETURN

[P7]
10 FOR J=0 TO W:NEXT J:RETURN

[P8]
10 GOTO 10+Y
11 FOR R=1 TO 0 STEP-1:PRINT CSR X;P$(R);:GOSUB #7:NEXT R:RETURN
12 PRINT CSR 2;K$;:GOSUB #7:RETURN

[P9]
10 VAC:N$="HIE":T=160:GOTO #0
20 "BRAVE SAGA "
30 " 2014/01/19"
40 " AUTHOR:HIE"
変数表
変数 説明
各種データ定義用
エリア
B$〜H$ マップデータ定義・取得・判定用…B$(0)〜B$(6)
I,J ループ用(汎用)
K$ キー入力
ボーナスフラグ($取得数)
M$ マップ表示用
N$ ハイスコアラー
ジャンプ用
P$,Q$ キャラクタデータ定義用
プレイヤー状態
スコア
ハイスコア
U,V 各種データ取得用
ウェイト調整用
表示座標用(汎用)
制御用
難易度調整用
 
プログラムマップ
[P0] メインルーチン(1049step)
行番号 説明
10 初期設定(各種初期データ定義)
20 タイトル、ハイスコアラー表示
30〜90 ゲーム開始前処理(変数設定、デモ、エリア数表示)
100 エリアマップデータ作成
110 画面表示設定
120〜150 地形データ判定
160〜180 キー入力判定
190 ジャンプ処理
200〜220 エリアマップデータ定義
230〜240 地形データ判定用サブルーチン
250 チェックポイント到着処理
260〜280 ゴール到着処理
290〜340 ゲームオーバー処理
350〜370 エンディング処理
[P1] エリアマップデータ(426step)
行番号 説明
10 エリアマップデータ取得制御
11〜13 エリアマップ1データ
21〜23 エリアマップ2データ
31〜33 エリアマップ3データ
41〜43 エリアマップ4データ
[P7] ウェイト制御(14step)
行番号 説明
10 表示ウェイト処理
[P8] 画面表示制御(56step)
行番号 説明
10 画面表示判定処理
11 ジャンプ表示処理
12 メッセージ表示処理
[P9] イニシャライズ(23step ※注釈行含めず)
行番号 説明
10 初期設定
20〜40 注釈行※この行以降は無視
 
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
¥CI
× ¥CR

 

COMMENT







   

PAGE TOP